72caf5920f
git-svn-id: https://swig.svn.sourceforge.net/svnroot/swig/trunk@10904 626c5289-ae23-0410-ae9c-e8d60b6d4f22
81 lines
2 KiB
Text
81 lines
2 KiB
Text
dnl Process this file with autoconf to produce a configure script.
|
|
|
|
AC_INIT()
|
|
AC_PREREQ(2.52)
|
|
|
|
AC_MSG_NOTICE([Configuring ccache])
|
|
|
|
AC_CONFIG_HEADER(config.h)
|
|
|
|
dnl Checks for programs.
|
|
AC_PROG_CC
|
|
AC_PROG_CPP
|
|
AC_PROG_INSTALL
|
|
|
|
AC_DEFINE([_GNU_SOURCE], 1,
|
|
[Define _GNU_SOURCE so that we get all necessary prototypes])
|
|
|
|
# If GCC, turn on warnings.
|
|
if test "x$GCC" = "xyes"
|
|
then
|
|
CFLAGS="$CFLAGS -Wall -W"
|
|
else
|
|
CFLAGS="$CFLAGS -O"
|
|
fi
|
|
|
|
AC_HEADER_DIRENT
|
|
AC_HEADER_TIME
|
|
AC_HEADER_SYS_WAIT
|
|
|
|
AC_CHECK_HEADERS(ctype.h strings.h stdlib.h string.h pwd.h)
|
|
|
|
AC_CHECK_FUNCS(realpath snprintf vsnprintf vasprintf asprintf mkstemp)
|
|
AC_CHECK_FUNCS(gethostname getpwuid)
|
|
|
|
AC_CACHE_CHECK([for compar_fn_t in stdlib.h],ccache_cv_COMPAR_FN_T, [
|
|
AC_TRY_COMPILE(
|
|
[#include <stdlib.h>],
|
|
[
|
|
void test_fn(void) { qsort(NULL, 0, 0, (__compar_fn_t)NULL); }
|
|
],
|
|
ccache_cv_COMPAR_FN_T=yes,ccache_cv_COMPAR_FN_T=no)])
|
|
if test x"$ccache_cv_COMPAR_FN_T" = x"yes"; then
|
|
AC_DEFINE(HAVE_COMPAR_FN_T, 1, [ ])
|
|
fi
|
|
|
|
AC_CACHE_CHECK([for C99 vsnprintf],ccache_cv_HAVE_C99_VSNPRINTF,[
|
|
AC_TRY_RUN([
|
|
#include <sys/types.h>
|
|
#include <stdarg.h>
|
|
void foo(const char *format, ...) {
|
|
va_list ap;
|
|
int len;
|
|
char buf[5];
|
|
|
|
va_start(ap, format);
|
|
len = vsnprintf(0, 0, format, ap);
|
|
va_end(ap);
|
|
if (len != 5) exit(1);
|
|
|
|
if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
|
|
|
|
exit(0);
|
|
}
|
|
main() { foo("hello"); }
|
|
],
|
|
ccache_cv_HAVE_C99_VSNPRINTF=yes,ccache_cv_HAVE_C99_VSNPRINTF=no,ccache_cv_HAVE_C99_VSNPRINTF=cross)])
|
|
if test x"$ccache_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
|
|
AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ])
|
|
fi
|
|
|
|
dnl Check for zlib.
|
|
AC_ARG_ENABLE([zlib],
|
|
AS_HELP_STRING([--enable-zlib], [enable zlib support for ccache compression]),,
|
|
[enable_zlib=yes])
|
|
|
|
if test x"$enable_zlib" = x"yes"; then
|
|
AC_CHECK_HEADER(zlib.h, AC_CHECK_LIB(z, gzdopen, LIBS="-lz $LIBS"; AC_DEFINE(ENABLE_ZLIB)))
|
|
fi
|
|
|
|
AC_CONFIG_FILES([Makefile])
|
|
AC_OUTPUT
|